home *** CD-ROM | disk | FTP | other *** search
/ PC World 2007 December / PCWorld_2007-12_cd.bin / v cisle / steadystate / SteadyState_Setup_ENU.exe / welcome.wsf < prev    next >
Encoding:
Extensible Markup Language  |  2007-04-17  |  21.0 KB  |  304 lines
  1.  ■<?xml version="1.0" ?>
  2. <package>
  3.     <comment>
  4.         ' *** 
  5.         ' *** ------------------------------------------------------------------------------
  6.         ' *** Filename:        Welcome.wsf
  7.         ' *** ------------------------------------------------------------------------------
  8.         ' *** Description:    Command line tool to enable/disable user accounts
  9.         ' *** ------------------------------------------------------------------------------
  10.         ' *** Version:        1.0
  11.         ' *** Notes:        
  12.         ' *** ------------------------------------------------------------------------------
  13.         ' *** Copyright (C) Microsoft Corporation 2005, All Rights Reserved
  14.         ' *** ------------------------------------------------------------------------------
  15.         ' *** 
  16.     </comment>
  17.     <job>
  18.     <runtime>
  19.         <description>Welcome Script</description>
  20.         <named name="enable"    required="false"  many="false"  helpstring="Adds the user account to Windows Welcome." />
  21.         <named name="disable"    required="false"  many="false"  helpstring="Removes the user account from Windows Welcome." />
  22.         <example>Example: Welcome.wsf /enable user</example>
  23.     </runtime>
  24.     
  25.         <resource id="IncorrectUsage">Incorrect Usage Detected</resource>
  26.         <resource id="ScriptName">Welcome.wsf</resource>
  27.         <resource id="EnableSuccess">The specified account has been added to Windows Welcome.</resource>
  28.         <resource id="DisableSuccess">The specified account has been removed from Windows Welcome.</resource>
  29.         <resource id="DomainMember1">This computer is part of a Windows domain.</resource>
  30.         <resource id="DomainMember2">The Windows Welcome screen will not display.</resource>
  31.         <resource id="InvalidUser">The specified account is not valid.</resource>
  32.         <resource id="AdminErrorMsg">You have to be an administrator to use this script.</resource>
  33.         <resource id="Enabled">The specified account has already been added to Windows Welcome.</resource>
  34.         <resource id="Disabled">The specified account has already been removed from Windows Welcome.</resource>
  35.         <resource id="CScriptMessage">Restarting script in command-line mode. Run CmdOn.BAT to set command-line mode as the default mode.</resource>
  36.         <resource id="CScriptTitle">Windows SteadyState: Windows Script Mode Detected</resource>
  37.         <resource id="FailToInit">Initialize objects failure, script will now quit.</resource>
  38.                 
  39.     <?job error="True" debug="False" ?>
  40.     
  41.         <script language="VBScript">
  42.         <![CDATA[
  43.             ' ~~~ 
  44.             ' ~~~ Force variables to be declared 
  45.             ' ~~~ 
  46.             Option Explicit
  47.             
  48.             ' ~~~ 
  49.             ' ~~~ Declare variables and constants
  50.             ' ~~~ 
  51.             Dim oWelcome, bOK, args, bResult
  52.             Dim bLocalUser, bDisabledUser, strRegPath
  53.             
  54.             Dim oShell, oWMIService, oNetwork, oUser
  55.             Dim sComputer
  57.             ' ~~~ Set the registry path
  58.             strRegPath = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\winlogon\SpecialAccounts\UserList\"
  60.             ' ~~~ Initialize objects
  61.             bOK = InitializeAllObjects
  62.             If Not(bOK) Then
  63.                 WScript.Echo getResource("FailToInit")
  64.                 Wscript.Quit()
  65.             End If
  66.             
  67.             ' ~~~ ------------------------------------------------------------------------------
  68.             ' ~~~ Check script usage
  69.             ' ~~~ ------------------------------------------------------------------------------
  70.             bOK = True
  71.             Set args = WScript.Arguments
  72.             Select Case args.Count
  73.                 Case 0 ,1,3
  74.                     bOK = False
  75.             End Select
  76.             
  77.             
  78.             If Not(bOK) Then
  79.                 WScript.Arguments.Showusage
  80.                 Wscript.Quit()
  81.             End If
  82.             
  83.             ' ~~~ ------------------------------------------------------------------------------
  84.             ' ~~~ Now do enable/disable
  85.             ' ~~~ ------------------------------------------------------------------------------
  86.             
  87.             ' ~~~ Enable the account 
  88.             If Wscript.Arguments.Named.Exists("enable") Then
  89.                 bOK = True
  90.                 bResult = EnableUser(args(1))
  91.                 If bResult = 0 Then
  92.                         WScript.Echo getResource("EnableSuccess")
  93.                         If DomainMember then 
  94.                             WScript.Echo getResource("DomainMember1")
  95.                             WScript.Echo getResource("DomainMember2")
  96.                         End If
  97.                 ElseIf bResult = 1 Then
  98.                         WScript.Echo getResource("InvalidUser")
  99.                         WScript.Arguments.Showusage
  100.                 ElseIf bResult = 2 Then    
  101.                         WScript.Echo getResource("Enabled")
  102.                         If DomainMember then 
  103.                             WScript.Echo getResource("DomainMember1")
  104.                             WScript.Echo getResource("DomainMember2")
  105.                         End If
  106.                 End If                
  107.             End If
  108.             
  109.             ' ~~~ Disable the account
  110.             If Wscript.Arguments.Named.Exists("disable") Then
  111.                 bOK = True
  112.                 bResult = DisableUser(args(1))
  113.                 If bResult = 0 Then
  114.                     WScript.Echo getResource("DisableSuccess")
  115.                     If DomainMember then 
  116.                         WScript.Echo getResource("DomainMember1")
  117.                         WScript.Echo getResource("DomainMember2")
  118.                     End If
  119.                 ElseIf bResult = 1 Then
  120.                     WScript.Echo getResource("InvalidUser")
  121.                     WScript.Arguments.Showusage
  122.                 ElseIf bResult = 2 Then
  123.                     WScript.Echo getResource("Disabled")
  124.                     If DomainMember then 
  125.                         WScript.Echo getResource("DomainMember1")
  126.                         WScript.Echo getResource("DomainMember2")
  127.                     End If
  128.                 End If
  129.             End If
  130.     
  131.             ' ~~~ If user input the wrong command, echo the usage        
  132.             If Not(Wscript.Arguments.Named.Exists("enable")) AND Not(Wscript.Arguments.Named.Exists("disable")) Then
  133.                 WScript.Arguments.Showusage
  134.             End If
  135.             
  136.             ' ~~~ Destroy objects
  137.             UnLoadObjects()
  138.             Set oWelcome = nothing
  141.             ' ***
  142.             ' *** --------------------------------------------------------------------------------
  143.             ' *** Name:         SetUser()
  144.             ' *** --------------------------------------------------------------------------------
  145.             ' *** Purpose:        Sets and checks the user that we want to add or remove from
  146.             ' ***            the welcome screen
  147.             ' *** --------------------------------------------------------------------------------
  148.             ' ***
  149.             Sub SetUser(strUser)
  150.                 On Error Resume Next
  152.                 Dim strDisabled
  154.                 ' Check if this user is local or not
  155.                 Set oUser = GetObject("WinNT://" & sComputer & "/" & strUser & ",user")
  156.                 If Err.Number <> 0 Then
  157.                     ' ~~~ Couldn't find the user, doesn't exist
  158.                     bLocalUser = False
  159.                 Else
  160.                     ' ~~~ User exists!
  161.                     bLocalUser = True
  162.                 End If
  164.                 ' Check if this user is disabled or not
  166.                 strdisabled = oShell.RegRead(strRegPath & strUser)
  168.                 If IsEmpty(strdisabled) Then
  169.                     bDisabledUser = False
  170.                 Else
  171.                     bDisabledUser = True
  172.                 End If    
  173.             End Sub
  175.             ' ***
  176.             ' *** ------------------------------------------------------------------------------
  177.             ' *** Name:        EnableUser
  178.             ' *** ------------------------------------------------------------------------------
  179.             ' *** Purpose:    Enables the user account, by removing the account from the
  180.             ' ***        UserList Key of the SpecialAccounts in the reigstry.
  181.             ' *** ------------------------------------------------------------------------------
  182.             ' ***
  183.             Function EnableUser(strUser)
  184.                 On Error Resume Next
  186.                 SetUser(strUser)
  187.                 If bLocalUser Then
  188.                     If bDisabledUser = False Then 
  189.                         ' ~~~ Account already disabled
  190.                         EnableUser = 2
  191.                     Else
  192.                         ' ~~~ Add account to Special Accounts list
  193.                         Call oShell.RegDelete(strRegPath & strUser)
  194.                         EnableUser = 0
  195.                     End If
  196.                 Else
  197.                     ' ~~~ Not a local account
  198.                     EnableUser = 1
  199.                 End If
  200.             End Function
  202.             ' ***
  203.             ' *** ------------------------------------------------------------------------------
  204.             ' *** Name:        DisableUser
  205.             ' *** ------------------------------------------------------------------------------
  206.             ' *** Purpose:    Disables the user account, by adding the account in the
  207.             ' ***        UserList Key of the SpecialAccounts in the  reigstry.
  208.             ' *** ------------------------------------------------------------------------------
  209.             ' ***
  210.             Function DisableUser(strUser)
  211.                 On Error Resume Next
  213.                 SetUser(strUser)
  214.                 If bLocalUser Then
  215.                     If bDisabledUser = True Then
  216.                         ' ~~~ Account already disabled
  217.                         DisableUser = 2
  218.                     Else
  219.                         ' ~~~ Disable the account by adding it to the Special Accounts list
  220.                         Call oShell.RegWrite(strRegPath & strUser, 0, "REG_DWORD")
  221.                         DisableUser = 0
  222.                     End If
  223.                 Else
  224.                     ' ~~~ Not a local account
  225.                     DisableUser = 1
  226.                 End If
  227.             End Function
  229.             ' *** 
  230.             ' *** ------------------------------------------------------------------------------
  231.             ' *** Name:            DomainMember()
  232.             ' *** ------------------------------------------------------------------------------
  233.             ' *** Purpose:        Determines if machine is a member of a Windows Domain
  234.             ' *** ------------------------------------------------------------------------------
  235.             ' *** 
  236.             Function DomainMember()
  237.                 On Error Resume Next
  238.                 Dim oComputer, oComputers
  240.                 Set oComputers  = oWMIService.ExecQuery("Select DomainRole from Win32_ComputerSystem")
  241.                 For Each oComputer in oComputers
  242.                     If oComputer.DomainRole=1 Then
  243.                         DomainMember = True
  244.                     Else
  245.                         DomainMember = False
  246.                     End If
  247.                 Next
  248.             End Function
  249.             
  250.             ' *** 
  251.             ' *** ------------------------------------------------------------------------------
  252.             ' *** Name:            InitializeAllObjects()
  253.             ' *** ------------------------------------------------------------------------------
  254.             ' *** Purpose:        This function Initialises all the objects required
  255.             ' *** ------------------------------------------------------------------------------
  256.             ' *** 
  257.             Function InitializeAllObjects()
  258.                 On Error Resume Next
  259.                 Dim bReturn
  260.                 bReturn = True
  262.                 Set oShell = createobject("wscript.shell")
  263.                 If TypeName(oShell) <> "IWshShell3" Then 
  264.                     bReturn = False
  265.                 End If                    
  266.                 
  267.                 Set oNetwork = CreateObject("Wscript.Network")
  268.                 If TypeName(oNetwork) <> "IWshNetwork2" Then 
  269.                     bReturn = False
  270.                 End If                    
  271.                 sComputer  = oNetwork.ComputerName
  272.                 
  273.                 Set oWMIService = GetObject("winmgmts:" _
  274.                     & "{impersonationLevel=impersonate}!\\" & "." & "\root\cimv2")
  275.                 If TypeName(oWMIService) <> "SWbemServicesEx" Then 
  276.                     bReturn = False
  277.                 End If
  278.                 
  279.                 
  280.                 InitializeAllObjects = bReturn
  282.             End Function
  283.             
  284.             ' *** 
  285.             ' *** ------------------------------------------------------------------------------
  286.             ' *** Name:            UnLoadObjects()
  287.             ' *** ------------------------------------------------------------------------------
  288.             ' *** Purpose:        This function Uninitialises all the objects
  289.             ' *** ------------------------------------------------------------------------------
  290.             ' *** 
  291.             Function UnLoadObjects()
  292.                 
  293.                 Set oUser = Nothing
  294.                 Set oShell = Nothing
  295.                 Set oNetwork = Nothing    
  296.                 Set oWMIService = Nothing
  297.                 
  298.             End Function
  299.         ]]>
  300.         </script>
  301.     </job>
  302. </package>